[原创]利用Curl和任务计划打造自动BT下载BOT

楼层直达

ikari

级别: 小荷初露

注册时间:: 2004-10-23

在线时间:: 0小时

发帖:: 181

只看楼主更多操作楼主发表于: 2006-07-31

诱因

豆腐一不抽烟二不喝酒，唯一可以算得上嗜好的就是 Anime 了。而且喜欢追新番，每周一集从不落下。
坐在电脑前第一首要的的事情就是翻翻各大BT页，看关注的动画是否出新，时间久了便成了习惯虽然繁琐却也不觉着有什么不便。
但最近即将因为工作的原因不得不到外地去一个月，而且多半驻地没有网络，难道只能等回来用 eMule 慢慢拖了么？
如果可以做到自动下载BT种子然后进而下载相应的文件就好了，上网搜刮一番却没有发现合用的现成软件，看来又只能 DIY 了。

思路

欲善其功，先利其器

最近CMD脚本用得顺手、Curl也正合我用，老搭档一出手BT种子应该是手到擒来才是。
接着是BT下载的问题，BitComet是豆腐常用的，翻翻说明有支持命令行。嗯，就是它了。
最后是自动定时运行，不需其它软件捉刀，Windows自带的任务计划足以。

知己知彼，百战不殆

要想从别人那里拿东西，当然就得熟悉别人的规矩。对于提供BT种子的网页要分别分析其结构才行，选择那些结构明晰的可以省不少功夫。
以豆腐常常出没的漫游BT页为例：
全部包含种子的条目都是在一个里面每个

元素里面的结构都是有序的分为置顶和一般两种情况。
如此一来就便于用 FOR 来取得相应的 URL。再看 href 里面的 HASH 值正是实际种子文件的文件名，这样用 CURL 来取是再方便不过了。
而且只要把每次已经下载的种子的文件名保存到一个外部文件，在反复执行的时候就可以通过比较来排除这些已经下载过的文件。

实践

为了顺藤摸瓜，先用 Curl 取得BT页的首页：

复制代码

curl -o tmp.txt [url]http://bt.popgo.net/[/url]

要顺利找到欲下载的符合只定条件的项目，FINDSTR 是不错的选择，这里豆腐以‘漫游字幕组’为关键字的即可收录所有该组的作品：

复制代码

'findstr "漫游字幕组" tmp.txt^|findstr "href"'

分析 tmp.txt 文件之后决定用‘=’和‘>’作分隔符，取出分割后的第5、6、9段字符串存入环境变量 i、j、k，
利用变量 i 来判断是否置顶的条目，如果是则 k 为种子文件名，否则 j 为种子文件名。
最后再对字符串作相应的截取处理，在代入 Curl 参数取得种子文件之前还要检查是否该文件已经被下载过了：

复制代码

for /f "tokens=5,6,9 delims==>" %%i in ('findstr "漫游字幕组" tmp.txt^|findstr "href"') do (
set flag=1
set tmp=%%i
if "!tmp:~1,2%!"=="置顶" (
set temp=%%k
set posthash=!temp:~0,-1%!
) else (
set temp=%%j
set posthash=!temp:~0,-1%!
)
for /f "delims=" %%j in (download.txt) do if !posthash!==%%j set flag=0
if !flag!==1 (
curl -O [url]http://bt.popgo.net/allowed/[/url]!posthash!.torrent
)
)

得到种子文件之后，用 START 命令来给 BitComet.exe 传送命令行参数启动BT下载。
‘/s’代表不需要确认立即开始下载的安静模式；‘/tray’代表启动时最小化到系统托盘；‘/o’代表储存文件的路径：

复制代码

start bitcomet.exe /s /tray !posthash!.torrent /o e:\downloads\

最后把已经下载过的文件名存入 download.txt 文件，以便下次使用：

复制代码

@echo !posthash!>>download.txt

完成

最终完整代码为：

复制代码

@echo off
setlocal ENABLEDELAYEDEXPANSION
curl -o tmp.txt [url]http://bt.popgo.net/[/url]
for /f "tokens=5,6,9 delims==>" %%i in ('findstr "漫游字幕组" tmp.txt^|findstr "href"') do (
set flag=1
set tmp=%%i
if "!tmp:~1,2%!"=="置顶" (
set temp=%%k
set posthash=!temp:~0,-1%!
) else (
set temp=%%j
set posthash=!temp:~0,-1%!
)
for /f "delims=" %%j in (download.txt) do if !posthash!==%%j set flag=0
if !flag!==1 (
curl -O [url]http://bt.popgo.net/allowed/[/url]!posthash!.torrent
start bitcomet.exe /s /tray !posthash!.torrent /o e:\downloads\
@echo !posthash!>>download.txt
)
)
endlocal